Packman Build Service PMBS

File handbrake.ebuild of Package handbrake (Revision 8)

Currently displaying revision 8 , Show latest

# $Id: PKGBUILD 74053 2012-07-18 17:33:26Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sebastien Piccand <sebcactus gmail com>

pkgname=('handbrake' 'handbrake-cli')
pkgver=0.9.8
pkgrel=28
arch=('i686' 'x86_64')
url="http://handbrake.fr/"
license=('GPL')
makedepends=('intltool' 'python2' 'yasm' 'wget' 'bzip2' 'gcc-libs' 'libnotify'
             'gstreamer0.10-base' 'gtk2' 'dbus-glib' 'fribidi')
source=(http://downloads.sourceforge.net/project/handbrake/$pkgver/HandBrake-$pkgver.tar.bz2)

build() {
  cd "$srcdir/HandBrake-$pkgver"
  mv "libhb/hb.h" "libhb/hb2.h"
  
  # Fix #include libhb
  for file in $(grep -R '#include "hb.h"' * 2>/dev/null | awk -F':' '{print $1}'); do sed -i 's/#include\ \"hb\.h\"/#include\ \"hb2\.h\"/g' ${file}; done
  # Use Python 2
  sed -i 's/python /python2 /' gtk/src/Makefile.am

#disable harfbuzz
  sed -i 's/--disable-png\ --disable-enca\ \\/--disable-png\ --disable-enca\ --disable-harfbuzz\ \\/g' "$srcdir/HandBrake-$pkgver/contrib/libass/module.defs"

./configure --prefix=/usr --force --disable-gtk-update-checks
  cd build
  make
}

package_handbrake() {
  pkgdesc="Multithreaded video transcoder"
  depends=('bzip2' 'gcc-libs' 'gstreamer0.10-base' 'libnotify' 'dbus-glib'
           'fribidi' 'gtk2' 'desktop-file-utils' 'hicolor-icon-theme')
  install=$pkgname.install

cd "$srcdir/HandBrake-$pkgver/build"

make DESTDIR="$pkgdir" install
  rm "$pkgdir/usr/bin/HandBrakeCLI"
}

package_handbrake-cli() {
  pkgdesc="Multithreaded video transcoder (CLI)"
  depends=('bzip2' 'gcc-libs' 'zlib' 'fribidi')

cd "$srcdir/HandBrake-$pkgver/build"
  install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
}

# vim:set ts=2 sw=2 et:
sha256sums=('dba75a9ff772e419c01d75532c1bf0d7253e73d7ead184eee755cd4c133dc798')